How to Setup a Call Control Object

Requirement: Contact Centre Licences

Overview

The Call Control Object allows you to manage inbound call routing entirely from Salesforce records — no routing policy changes needed. Admins can:

• Set weekly opening and closing hours (in local time)

• One Record to handle Holiday/Open hour rules on multiple policies

• Handle multiple time zones with automatic daylight saving adjustment

• Pre-set holiday routing and TTS messages using reusable slots

• Force lines closed for emergencies

• Dynamically route calls based on all of the above

Once created, you'll use a Query Object App in your routing policy to pull the record data, and a Rule App (Evaluate) to route calls based on the result.

How It Works

1. A call arrives at the routing policy

2. The Query Object App runs a query against your Call Control record

3. Salesforce evaluates all formula fields at query time (timezone conversion, holiday checks, open/closed status)

4. The Rule App (Evaluate) checks the returned values and routes the call:

   • Force Closed? → Play emergency message → Hang up/Voicemail

   • Holiday Active? → Play holiday message → Hang up/Voicemail

   • Out of Hours? → Play closed message → Hang up/Voicemail

   • None of the above? → Route to your normal call flow

Step 1: Create the Custom Object

1. Navigate to Setup → Object Manager → Create → Custom Object

2. Configure the following settings:

3. Click Save.

Step 2: Set Permissions

The Natterbox integration user (the user your Natterbox AVS connector authenticates as) needs Read access to this object and all its fields.

1. Go to Setup → Permission Sets (or Profiles)

2. Find the permission set/profile assigned to your Natterbox integration user

3. Under Object Settings, find Call Control

4. Enable Read access on the object

5. Enable Read access on all fields

Step 3: Create a Tab

1. Go to Setup → Tabs → Custom Object Tabs → New

2. Select Call Control as the object

3. Choose a Tab Style (the clock icon works well)

4. Add it to the relevant App (e.g., your Natterbox app or admin app)

5. Click Save

Step 4: Create the Fields

Navigate to Setup → Object Manager → Call Control → Fields & Relationships → New for each field below.

IF(TEXT(DST_Rule__c) = "US",
  AND(
    TODAY() >= DATE(YEAR(TODAY()), 3, 8) + MOD(1 - WEEKDAY(DATE(YEAR(TODAY()), 3, 8)) + 7, 7),
    TODAY() < DATE(YEAR(TODAY()), 11, 1) + MOD(1 - WEEKDAY(DATE(YEAR(TODAY()), 11, 1)) + 7, 7)
  ),
  IF(TEXT(DST_Rule__c) = "EU",
    AND(
      TODAY() >= DATE(YEAR(TODAY()), 3, 31) - MOD(WEEKDAY(DATE(YEAR(TODAY()), 3, 31)) - 1, 7),
      TODAY() < DATE(YEAR(TODAY()), 10, 31) - MOD(WEEKDAY(DATE(YEAR(TODAY()), 10, 31)) - 1, 7)
    ),
    false
  )
)

TIMEVALUE(NOW() + ((UTC_Offset__c + IF(DST_Active__c, 1, 0)) / 24))

CASE(
  WEEKDAY(TODAY()),
  2, Monday_Open__c,
  3, Tuesday_Open__c,
  4, Wednesday_Open__c,
  5, Thursday_Open__c,
  6, Friday_Open__c,
  7, Saturday_Open__c,
  Sunday_Open__c
)

CASE(
  WEEKDAY(TODAY()),
  2, Monday_Closed__c,
  3, Tuesday_Closed__c,
  4, Wednesday_Closed__c,
  5, Thursday_Closed__c,
  6, Friday_Closed__c,
  7, Saturday_Closed__c,
  Sunday_Closed__c
)

AND(
  NOT(ISBLANK(Open_Today__c)),
  Current_Time__c >= Open_Today__c,
  Current_Time__c <= Closed_Today__c
)

OR(
  AND(NOT(ISBLANK(Holiday_1_Start__c)), NOW() >= Holiday_1_Start__c, NOW() <= Holiday_1_End__c),
  AND(NOT(ISBLANK(Holiday_2_Start__c)), NOW() >= Holiday_2_Start__c, NOW() <= Holiday_2_End__c),
  AND(NOT(ISBLANK(Holiday_3_Start__c)), NOW() >= Holiday_3_Start__c, NOW() <= Holiday_3_End__c),
  AND(NOT(ISBLANK(Holiday_4_Start__c)), NOW() >= Holiday_4_Start__c, NOW() <= Holiday_4_End__c),
  AND(NOT(ISBLANK(Holiday_5_Start__c)), NOW() >= Holiday_5_Start__c, NOW() <= Holiday_5_End__c)
)

IF(AND(NOT(ISBLANK(Holiday_1_Start__c)), NOW() >= Holiday_1_Start__c, NOW() <= Holiday_1_End__c), Holiday_1_Message__c,
IF(AND(NOT(ISBLANK(Holiday_2_Start__c)), NOW() >= Holiday_2_Start__c, NOW() <= Holiday_2_End__c), Holiday_2_Message__c,
IF(AND(NOT(ISBLANK(Holiday_3_Start__c)), NOW() >= Holiday_3_Start__c, NOW() <= Holiday_3_End__c), Holiday_3_Message__c,
IF(AND(NOT(ISBLANK(Holiday_4_Start__c)), NOW() >= Holiday_4_Start__c, NOW() <= Holiday_4_End__c), Holiday_4_Message__c,
IF(AND(NOT(ISBLANK(Holiday_5_Start__c)), NOW() >= Holiday_5_Start__c, NOW() <= Holiday_5_End__c), Holiday_5_Message__c,
"")))))

Step 5: Configure the Page Layout

1. Navigate to Setup → Object Manager → Call Control → Page Layouts

2. Click on the default layout

3. Organise fields into sections:

Section 1 — Settings (single column)

• Routing Policy Name

• UTC Offset

• DST Rule

Section 2 — Opening Hours (2-column)

Section 3 — Status (single column, all read-only)

• DST Active

• Current Time

• Open Today

• Closed Today

• Currently Open

Section 4 — Holidays (2-column)

Section 5 — Overrides (single column)

• Force Closed

• Force Closed Message

4. Click Save

Step 6: Create Your Records

Create a record for each unique schedule you need. If multiple routing policies share the same opening hours, timezone, and holidays, they can all point to the same record — no need to duplicate.

Example: If your UK Sales, UK Support, and UK Billing policies all follow the same hours and holidays, create one record called UK Standard Hours and point all three routing policies at the record using the same query. Update hours or holidays once, and it applies everywhere.

For policies with different schedules (different timezone, different hours, different holidays), create a separate record.

Filling in Opening Hours

• Enter all times in local time — the formulas handle timezone conversion automatically

• If the line is closed on a particular day (e.g., weekends), leave both the Open and Closed fields blank for that day. A blank day will always evaluate as closed.

• If the line has different hours on different days (e.g., closes early on Fridays), just enter the different times for that day

• Times use 24-hour format: 09:00, 17:30, 22:00, etc.

Filling in Holiday Slots

• Use any available slot for any holiday — the slot number doesn't matter, they're checked in order

• Once a holiday has passed, you can clear the slot and reuse it for the next one, or leave old holidays in place (they won't trigger once the end date has passed)

• Leave all 4 fields blank for unused slots — they'll be ignored by the formula

Writing Messages (TTS)

The text you enter in Holiday Message and Force Closed Message fields is read aloud to callers by the Text-to-Speech (TTS) engine. Keep the following in mind:

• Language: The message must be written in the language that matches the TTS voice configured in your routing policy. If your policy uses an English voice, write in English. If it uses a French voice, write in French.

Example record:

Part 2: Building the Routing Policy

Step 7: Add the Query Object App

In your routing policy, inside an Action Container (placed after Inbound Numbers):

1. Add a Query Object app

2. Configure:

   - Record Type = Call Control

   - Filter Results (Routing Policy Name) = (Testing Policy)  
   (Replace “Testing Policy” with the name of your Call Control record you created)

   - Return Fields (Currently Open), (Holiday Active), (Holiday Message), (Force Closed), (Force Closed Message)

Macro Reference

When the Query Object App retrieves a record, all returned fields are stored as macros using this format:

$(SForce_ResultSetName.FieldAPIName)

With the Result Set (Query Component Name) named CallControl:

Step 8: Add Rules

Add a new Action Container, after the Query Object and connect all nodes:

1. Add 3 Rule apps

2. Order matters — Force Closed → Holiday → Out of Hours → Open. Most restrictive first.

3. Configure:

Step 9: Setting up closure messages in the TTS Speak App

After each rule rule:

1. Add a speak app

2. Configure:

Each speak component can have its respective Macro added and voice set.

Force Close Message - $(SForce_CallControl.Force_Closed_Message__c)

Holiday Message - $(SForce_CallControl.Holiday_Message__c)

Out of Hours - This will be a static TTS message as it does not need to change frequently. Optionally you could add another field under the call control object to capture this input if desired.

Step 10: Open Hours Flow

If none of the above rules trigger, the call falls through to the next app below — this is your open/in-hours flow. Connect to your normal routing (Hunt Group, Call Queue, Connect a Call, etc.).

Key Points

• Rules trigger on match — if the condition is met, the call routes via the middle connector. If not, it passes to the next app below.

• Order matters — Force Closed → Holiday → Out of Hours → Open. Most restrictive first.

• One record per schedule — each has its own timezone, hours, and holidays.

• Admins enter local times — formulas handle UTC conversion automatically.

• One rule for all holidays — generic slots mean you never touch the policy to add a new holiday.

• No policy changes needed — admins manage everything from the Salesforce record.

Testing

1. Set a test record's hours to a window you can test within

2. Call the number assigned to that policy

3. Verify the call routes correctly for open/closed

4. Toggle Force Closed and call again — confirm the override message plays

5. Set a holiday slot window that includes now — confirm the holiday message plays

6. Check the formula fields on the record to verify Currently Open, Current Time, DST Active, and Holiday Active are calculating correctly

Timezone Reference

*For AU/NZ timezones, add additional IF branches to the DST_Active__c formula with the appropriate transition dates for those regions.